Navigation

• Main Page

• Random Page
• Create a new Page

• What's New?

• All Pages
• Categories

• Administration
• File Management

• Login/Logout
• Your Profile

• Page Editing Help
• Sandbox Page

ScrewTurn Wiki - My Plugins

Download links

• MyPlugins.zip
• AlphaIndex.zip
• ExternalPageProvider.zip

MyPlugins.zip

General

Individual plugins

* [AllPages.aspx?Cat=Community|Community]
* [AllPages.aspx?Cat=Development|Development]
* [AllPages.aspx?Cat=-|Uncategorized]

Release notes (updates from original version)

AlphaIndex.zip

ExternalPageProvider.zip

Delegate Function File2WikiText(ByVal fn As String) As String

MyCodeFormatter.dll

1. Created a class library project name MyCodeFormatter.dll. Referenced Screwturn.Wiki.PluginFramework.dll and CSharpFormat.dll.
2. Created the following class:

Option Explicit On
Option Strict On

Imports System
Imports System.Collections.Generic
Imports ScrewTurn.Wiki.PluginFramework
Imports Manoli.Utils

Public Class CodeFormatterClass
    Implements IFormatterProvider

    Private Shared NewLineCharArray() As Char = Microsoft.VisualBasic.ControlChars.CrLf.ToCharArray
    Private Shared WhiteSpaceCharArray() As Char = (" " & Microsoft.VisualBasic.ControlChars.CrLf & Microsoft.VisualBasic.ControlChars.Tab).ToCharArray

    Private _host As IHost = Nothing
    Private MyStyleSheet As String = ""
    Private fmtdict As New Dictionary(Of String, CSharpFormat.SourceFormat)

    Private Class ParmDictClass
        Inherits Dictionary(Of String, String)

        Public Function ItemAsBool _
         (ByVal parmname As String) As Boolean

            If Me.ContainsKey(parmname) = False Then Return False

            Dim s As String = Item(parmname)
            If s Is Nothing Then Return False
            'anything that starts with "Y" or "T" is "true": 
            'intended values: true, false, yes, no
            Return ("tTyY".IndexOf(s.Chars(0)) >= 0)
        End Function

        Public Function ItemAsStr _
            (ByVal parmName As String) As String

            If Not Me.ContainsKey(parmName) Then Return ""
            Return Item(parmName)
        End Function

        Public Shared Function ParseCodeTag(ByVal tag As String) _
            As ParmDictClass

            Dim tmp As New ParmDictClass
            If tag Is Nothing Then Return tmp
            If tag.Length <= 6 Then Return tmp

            tag = tag.Substring(5, tag.Length - 6).Trim.ToLower
            If tag.Length = 0 Then Return tmp

            Dim aParms() As String = tag.Split(WhiteSpaceCharArray, StringSplitOptions.RemoveEmptyEntries)
            For Each Parm As String In aParms
                Dim a() As String = Parm.Split("="c)
                Dim parmKey As String = ""
                Dim parmVal As String = ""
                If a.Length = 1 Then
                    parmKey = "lang" 'parm without key names is the "lang" parm
                    parmVal = StripQuotes(a(0))
                Else
                    parmKey = a(0)
                    parmVal = StripQuotes(a(1))
                End If

                If tmp.ContainsKey(parmKey) Then
                    tmp(parmKey) = parmVal
                Else
                    tmp.Add(parmKey, parmVal)
                End If
            Next
            Return tmp
        End Function
    End Class

    Private Shared Function CountLeadingSpaces(ByVal s As String) As Integer
        If s Is Nothing Then Return -1
        If s.Length = 0 Then Return -1

        Dim n As Integer = 0
        For i = 0 To s.Length - 1
            If s.Chars(i) <> " "c Then Return i
        Next
        Return -1 'all spaces? treat as if it was empty
    End Function

    Private Shared Function StripLeadingSpaces(ByVal s As String) As String
        If s Is Nothing Then Return ""

        Dim buf As New Text.StringBuilder
        Dim lines As New List(Of String)
        lines.AddRange(s.Split(NewLineCharArray, StringSplitOptions.RemoveEmptyEntries))

        Do Until lines.Count = 0 OrElse lines(0).Trim.Length > 0
            lines.RemoveAt(0)
        Loop
        Do Until lines.Count = 0 OrElse lines(lines.Count - 1).Trim.Length > 0
            lines.RemoveAt(lines.Count - 1)
        Loop

        Dim result As Integer = -1
        For i = 0 To lines.Count - 1
            Dim n As Integer = CountLeadingSpaces(lines(i))
            If n = 0 Then
                result = -1
                Exit For
            End If
            If n <> -1 AndAlso (n < result OrElse result = -1) Then result = n
        Next
        If result > 0 Then
            For i = 0 To lines.Count - 1
                lines(i) = lines(i).Substring(result)
            Next
        End If

        For i = 0 To lines.Count - 1
            buf.AppendLine(lines(i))
        Next
        Return buf.ToString
    End Function

    Private Shared Function StripQuotes(ByVal s As String) As String
        If s Is Nothing Then Return ""
        If s.Length < 2 Then Return s

        If s.Chars(0) = """"c _
        AndAlso s.Chars(s.Length - 1) = """"c Then
            Return s.Substring(1, s.Length - 2)
        End If

        Return s
    End Function

    'Private Shared Function TextOnlyFormatter(ByVal code As String) As String
    '    code = code.Replace("&", "&amp;")
    '    code = code.Replace("&", "&amp;")
    '    code = code.Replace("<", "&lt;")
    '    code = code.Replace(">", "&gt;")
    '    Return "<pre class=""csharpcode"">" & code & "</pre>"
    'End Function

    Private Function TextOnlyFormatter(ByVal code As String) As String
        If code Is Nothing Then Return ""

        Dim buf As New Text.StringBuilder(CInt(code.Length * 1.25))
        buf.Append("<pre class=""csharpcode"">")
        Dim prevPos As Integer = 0
        Dim currPos As Integer = code.IndexOfAny("&<>".ToCharArray, 0)
        Do Until currPos < 0
            If currPos > prevPos Then
                buf.Append(code.Substring(prevPos, currPos - prevPos))
            End If
            Select Case code.Chars(currPos)
                Case "&"c
                    buf.Append("&amp;")
                Case "<"c
                    buf.Append("&lt;")
                Case ">"c
                    buf.Append("&gt;")
            End Select
            prevPos = currPos + 1
            currPos = code.IndexOfAny("&<>".ToCharArray, prevPos)
        Loop

        currPos = code.Length
        If currPos > prevPos Then
            buf.Append(code.Substring(prevPos, currPos - prevPos))
        End If
        buf.Append("</pre>")

        Return buf.ToString
    End Function

    Private Function FindOpenTag(ByVal raw As String, ByVal startPos As Integer) As Integer
        'since the start tag can be either be <code> or <code langParm>,
        'we need to search for "<code" and then check that the 5th character
        'is either a space or a greater-than symbol. If we just find <code 
        'without one of those 2 things, we should keep searching until 
        'we find another one or we find nothing and return a negative value.
        Const OpenTag As String = "<code"
        Const gt As Char = ">"c
        Dim p1 As Integer = raw.IndexOf(OpenTag, startPos, StringComparison.CurrentCultureIgnoreCase)
        Do While p1 > 0 AndAlso raw.Chars(p1 + OpenTag.Length) <> gt _
        AndAlso raw.Chars(p1 + OpenTag.Length) <> " "c
            p1 = raw.IndexOf(OpenTag, p1 + 1, StringComparison.CurrentCultureIgnoreCase)
        Loop
        Return p1
    End Function

    Public Function Format _
        (ByVal raw As String, _
         ByVal context As ContextInformation, _
         ByVal phase As FormattingPhase) As String _
            Implements IFormatterProvider.Format

        If raw Is Nothing Then Return ""

        Const CloseTag As String = "</code>"
        Const gt As Char = ">"c

        Try
            Dim firstTime As Boolean = True
            Dim pOpenTagStart As Integer = FindOpenTag(raw, 0)

            Do Until pOpenTagStart < 0
                If firstTime Then
                    raw = MyStyleSheet & Microsoft.VisualBasic.ControlChars.CrLf & raw
                    pOpenTagStart += MyStyleSheet.Length + 2
                    firstTime = False
                End If

                Dim pCloseTag As Integer = raw.IndexOf(CloseTag, pOpenTagStart, StringComparison.CurrentCultureIgnoreCase)
                Dim pOpenTagClose As Integer = raw.IndexOf(gt, pOpenTagStart)
                If pCloseTag >= 0 And pCloseTag > pOpenTagClose Then
                    Dim code As String = StripLeadingSpaces(raw.Substring(pOpenTagClose + 1, pCloseTag - pOpenTagClose - 1))
                    code = code.Replace("&null", "")
                    Dim tag As String = raw.Substring(pOpenTagStart, pOpenTagClose - pOpenTagStart + 1)
                    Dim parms As ParmDictClass = ParmDictClass.ParseCodeTag(tag)
                    Dim lang As String = parms.ItemAsStr("lang")

                    If fmtdict.ContainsKey(lang) Then
                        fmtdict(lang).EmbedStyleSheet = False
                        fmtdict(lang).Alternate = parms.ItemAsBool("alternate")
                        fmtdict(lang).LineNumbers = parms.ItemAsBool("linenumbers")
                        fmtdict(lang).TabSpaces = 4
                        code = fmtdict(lang).FormatCode(code)
                    Else
                        code = TextOnlyFormatter(code)
                    End If

                    raw = raw.Substring(0, pOpenTagStart) & "<nowiki>" & code & "</nowiki>" & raw.Substring(pCloseTag + 7)
                End If

                If pCloseTag < 0 Then pCloseTag = pOpenTagStart
                pOpenTagStart = FindOpenTag(raw, pCloseTag)
            Loop
        Catch ex As Exception
            Return "<pre>" & ex.Message & ex.StackTrace & "</pre>"
        End Try
        Return raw
    End Function

    Public ReadOnly Property PerformPhase1() As Boolean Implements IFormatterProvider.PerformPhase1
        Get
            Return True
        End Get
    End Property

    Public ReadOnly Property PerformPhase2() As Boolean _
        Implements IFormatterProvider.PerformPhase2
        Get
            Return False
        End Get
    End Property

    Public ReadOnly Property PerformPhase3() As Boolean _
        Implements IFormatterProvider.PerformPhase3
        Get
            Return False
        End Get
    End Property

    Public ReadOnly Property Information() As ComponentInformation Implements IProvider.Information
        Get
            Return New ComponentInformation("MyCodeFormatter", "Mike Mestemaker", "")
        End Get
    End Property

    Public Sub Init(ByVal host As IHost, ByVal config As String) Implements IProvider.Init
        MyStyleSheet = "<style type=""text/css"">" & _
            CompressCSS.Exec(CSharpFormat.SourceFormat.GetCssString) & _
            "</style>"

        _host = host

        Dim tmp As CSharpFormat.SourceFormat

        tmp = New CSharpFormat.VisualBasicFormat
        fmtdict.Add("vb.net", tmp)
        fmtdict.Add("vb", tmp)
        fmtdict.Add("visual basic", tmp)
        fmtdict.Add("vbscript", tmp)
        tmp = New CSharpFormat.CSharpFormat
        fmtdict.Add("cs", tmp)
        fmtdict.Add("c#", tmp)
        fmtdict.Add("c", tmp)
        fmtdict.Add("c++", tmp)
        tmp = New CSharpFormat.HtmlFormat
        fmtdict.Add("xml", tmp)
        fmtdict.Add("html", tmp)
        tmp = New CSharpFormat.JavaScriptFormat
        fmtdict.Add("js", tmp)
        fmtdict.Add("javascript", tmp)
        tmp = New CSharpFormat.TsqlFormat
        fmtdict.Add("sql", tmp)

    End Sub

    Public Sub Shutdown() Implements IProvider.Shutdown
        fmtdict.Clear()
        _host = Nothing
    End Sub
End Class

Imports System
Imports System.Text.RegularExpressions

Public Class CompressCSS
    Public Shared Function Exec(ByVal body As String) As String
        body = Regex.Replace(body, "/\*.+?\*/", "", RegexOptions.Singleline)
        body = body.Replace("  ", String.Empty)
        body = body.Replace(Environment.NewLine + Environment.NewLine + Environment.NewLine, String.Empty)
        body = body.Replace(Environment.NewLine + Environment.NewLine, Environment.NewLine)
        body = body.Replace(Environment.NewLine, String.Empty)
        body = body.Replace("\t", String.Empty)
        body = body.Replace(" {", "{")
        body = body.Replace(" :", ":")
        body = body.Replace(": ", ":")
        body = body.Replace(", ", ",")
        body = body.Replace("; ", ";")
        body = body.Replace(";}", "}")
        body = Regex.Replace(body, "/\*[^\*]*\*+([^/\*]*\*+)*/", "$1")
        body = Regex.Replace(body, "(?<=[>])\s{2,}(?=[<])|(?<=[>])\s{2,}(?=&nbsp;)|(?<=&ndsp;)\s{2,}(?=[<])", String.Empty)

        Return body
    End Function
End Class

ILMerge /out:CodeFormatter.dll MyCodeFormatter.dll CSharpFormat.dll

<code lang="vb" alternate="true" linenumbers="true">
</code>